kg=1; m=1; sek=1; (* Einheiten *) 
set={"GlobalAdaptive","MaxErrorIncreases"->100,
Method->"GaussKronrodRule"}; (* Integrationsregel *)
int[F_,{x_,y_,z_}]:=Quiet[NIntegrate[F,{x,y,z}, Method->set, MaxRecursion->n]];
n=100; (* Rekursionstiefe *)
tE=200 Gyr;  (* Obere Zeitgrenze *) 
c=299792458m/sek; (* Licht *) 
G=667384*^-16(m^3)(kg^(-1))(sek^(-2));  (* Newtons Konstante *) 
Gyr=(10^7)*36525*24*3600*sek; (* Gigalichtjahr *) 
Glyr=Gyr*c; (* Gigajahr *) 
Mpc=30856775777948584200000m; (* Megaparsek *) 
kB=13806488*^-30kg (m^2)/(sek^2)/K; (* Boltzmanns Konstante *) 
h=662606957*^-42kg (m^2)/sek; (* Plancks Konstante *) 
ρc[H_]:=3 (H^2)/8/π/G; (* Kritische Dichte *) 
ρR=8(π^5)(kB^4)(T^4)/15/(c^5)/(h^3); (* Strahlungsdichte *) 
T=2725/1000K; (* CMB Temperatur *) 
H0=67150m/Mpc/sek; (* Hubbles Konstante *)
ΩR=ρR/ρc[H0]; ΩM=317/1000; Ωb=49/1000; ΩΛ=683/1000-ΩR; ΩT=ΩR+ΩM+ΩΛ; ΩK=1-ΩT;(* Dichteparameter *) 
F[a_]:=(Sqrt[ΩR (a^(-4))+ΩM (a^(-3))+ΩK (a^(-2))+ΩΛ]); (* Dichtefunktion *) 
H[a_]:=H0 F[a]; (* Hubble Parameter *) 
ta[A_]:=int[1/a/ H[a], {a,0,A}]; (* t nach a *) 
α[τ_]:=A/.Quiet[FindRoot[ta[A]-τ, {A,1}]] (* a nach t *) 
rH[τ_]:=c/H[α[τ]]; (* Hubble Radius *)
lC[τ_]:=int[-c α[τ]/(a^2)/H[a],{a,1,α[τ]}]; (* Lichtkegel von t0 *) 
Lc[τ_, t_]:=int[-c α[τ]/(a^2)/H[a],{a,α[t],α[τ]}]; (* Lichtkegel von t *) 
pH[τ_]:=int[-α[τ] c/(a^2)/H[a],{a,α[τ],0}]; (* Partikelhorizont *) 
eH[τ_]:= α[τ]int [c/(α[т]), {т, τ, tE}]; (* Ereignishorizont *) 
t0=ta[1]; (* Alter des Universums *)

mHy=1.67372*^-27kg; nHy=40000; (* Wasserstoff *)
mHe=6.64648*^-27kg; nHe=3100; (* Helium *)
mOx=2.65676*^-26kg; nOx=22; (* Sauerstoff *)
mNe=3.35082*^-26kg; nNe=8.6; (* Neon *)
mNi=2.32587*^-26kg; nNi=6.6; (* Stickstoff *)
mCa=1.99442*^-26kg; nCa=3.5; (* Kohlenstoff *)
nA=nHy+nHe+nOx+nNe+nNi+nCa; 
MA=mHy nHy+mHe nHe+mOx nOx+mNe nNe+mNi nNi+mCa nCa;
mA=MA/nA; 
"Mittleres Atomgewicht"->mA "kg"

ρT=ρc[H0]; "Totale Diche"->N[ρT]"kg/(m^3)"

ρB=ρT Ωb;  "Baryonische Diche"->N[ρB]"kg/(m^3)"

V=4/3π ((pH[t0])^3); "Partikelhorizontvolumen"->N[V]"(m^3)"

Tn=ρB V/mA; "Anzahl"->Tn "Atome"

(* yukterez.net *)